home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / dviware / quicspool / wwfonts / troman.mf < prev    next >
Text File  |  1990-10-01  |  13KB  |  342 lines
  1. % $Header: troman.mf,v 1.1 88/01/15 13:15:20 simpson Rel $
  2. % $Log:    troman.mf,v $
  3. % Revision 1.1  88/01/15  13:15:20  simpson
  4. % initial release
  5. % 
  6. % Revision 0.1  88/01/07  08:15:18  simpson
  7. % beta test
  8. % 
  9. % The Computer Modern Roman family of fonts (by D. E. Knuth, 1979--1985)
  10.  
  11. if ligs>1: font_coding_scheme:="Troff text";
  12. else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
  13.   else: "TeX text without f-ligatures" fi;
  14.  spanish_shriek=oct"016"; spanish_query=oct"017"; fi
  15. minus=oct"004"; vertical=oct"174";
  16.  
  17. mode_setup; font_setup;
  18.  
  19. % We need to create space characters with no bitmap for \| and \^.  I put
  20. % them in oct"000" and oct"177" since these characters are not normally
  21. % used by ditroff.
  22. % My own creation (...creation being a generous term), for \|, 1/6 em
  23. beginchar(oct"000", 16/6u#, 0, 0);
  24. endchar;
  25.  
  26. % My own creation, for \^, 1/12 em
  27. beginchar(oct"177", 16/12u#, 0, 0);
  28. endchar;
  29.  
  30. % From the font lasy10.mf, file lasy.mf
  31. cmchar "Box";
  32. beginchar(oct"024",2.1math_axis#+4u#,v_center(7u#));
  33. italcorr math_axis#*slant;
  34. adjust_fit(0,0); pickup rule.nib;
  35. numeric a; a=round(2.1math_axis);
  36. x1=x4=good.x 2u; x2=x3=x1+a;
  37. y3=y4=.5(cap_height-a); y1=y2=y3+a;
  38. draw z1--z2--z3--z4--cycle;
  39. labels(1,2,3,4); endchar;
  40.  
  41. % Stolen from font cmsy10, file symbol.mf
  42. cmchar "Open bullet";
  43. beginchar(oct"025",9u#,v_center(7u#));
  44. adjust_fit(0,0); pickup rule.nib; autorounded;
  45. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
  46. circle_points; draw_circle;  % circle
  47. labels(1,2,3,4,5,6,7,8); endchar;
  48.  
  49. % Stolen from the font cmr10, file accent.mf
  50. cmchar "Umlaut (double dot) accent";
  51. numeric dot_diam#,dot_diam;
  52. dot_diam#=max(dot_size#,cap_curve#);
  53. beginchar(oct"026",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
  54. dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
  55. italcorr h#*slant+.5dot_diam#-2.25u#;
  56. adjust_fit(0,0);
  57. pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
  58. x1=x2=2.75u; top y2r=h+1;
  59. if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
  60. y1=.5[y2l,y2r]; dot(1,2);  % left dot
  61. pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
  62. dot(3,4);  % right dot
  63. penlabels(1,2,3,4); endchar;
  64.  
  65. % Stolen from the font cmr10.mf, file accent.mf
  66. cmchar "Cedilla accent";
  67. beginchar(oct"027",8u#,0,.875desc_depth#);
  68. adjust_fit(0,0);
  69. x1=.5w+.5u;
  70. if serifs: pickup crisp.nib; pos1(stem,0); pos2(stem,0);
  71.  pos3(vair,90); pos4(stem,0); pos5(vair,-90);
  72.  x1=x2; z3l=z2l; x4=x2+1.5u; x5=x3-1.5u;
  73.  bot y1=-o; bot y2=-vround 2/7d-o; y4=.5[y3,y5]; bot y5=-d-o;
  74.  filldraw stroke z1e--z2e;  % stem
  75.  filldraw stroke z3e{right}...z4e{down}...{left}z5e;  % hook
  76. else: pickup fine.nib; pos1(vair,0); top y1=-o-2;
  77.  pos2(.5[vair,stem],0); bot y2=-d-o; x2=x1-1.25u;
  78.  filldraw stroke z1e--z2e; fi  % diagonal
  79. penlabels(1,2,3,4,5); endchar;
  80.  
  81. % My own creation, a zero width period.  Used for dots in pic(1).
  82. cmchar "Dot for pic boxes";
  83. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  84. define_whole_blacker_pixels(dot_diam);
  85. beginchar(oct"030",0,dot_diam#,0);
  86. period_width#:=5u#; define_pixels(period_width);
  87. pickup fine.nib;
  88. pos1(dot_diam,0); pos2(dot_diam,90);
  89. lft x1l=hround(.5period_width-.5dot_diam); bot y2l=0; z1=z2; dot(1,2);  % dot
  90. penlabels(1,2); endchar;
  91.  
  92. % My own creation.  The fractions look like hell.
  93. cmchar "1/4 symbol";
  94. beginchar(oct"021", 12u#, body_height#, paren_depth#);
  95. italcorr body_height#*slant-.5u#;
  96. adjust_fit(0,0); pickup rule.nib;
  97. rt x1=hround(w-u)+eps; top y1=h+eps;
  98. lft x2=hround u-eps; bot y2=-d-eps;
  99. draw z1--z2;  % diagonal
  100. x3=x4=1/4w; y3=38/40h; y4=23/40h; 
  101. draw z3--z4;  % number 1
  102. x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
  103. draw z5--z6--z7--z8;
  104. endchar;
  105.  
  106. % My own creation
  107. cmchar "1/2 symbol";
  108. beginchar(oct"022", 12u#, body_height#, paren_depth#);
  109. italcorr body_height#*slant-.5u#;
  110. adjust_fit(0,0); pickup rule.nib;
  111. rt x1=hround(w-u)+eps; top y1=h+eps;
  112. lft x2=hround u-eps; bot y2=-d-eps;
  113. draw z1--z2;  % diagonal
  114. x3=x4=1/4w; y3=38/40h; y4=23/40h; 
  115. draw z3--z4;  % number 1
  116. x5=x9=.65w; x10=x7=.85w; x6=.74w;
  117. y9=y10=-.2d; y6=.37h; y5=.32h; y7=.30h;
  118. draw z5{dir 45}..z6..z7{dir -90}..{dir 225}z9; % number 2
  119. draw z9--z10;
  120. endchar;
  121.  
  122. % My own creation.
  123. cmchar "3/4 symbol";
  124. beginchar(oct"023", 12u#, body_height#, paren_depth#);
  125. italcorr body_height#*slant-.5u#;
  126. adjust_fit(0,0); pickup rule.nib;
  127. rt x1=hround(w-u)+eps; top y1=h+eps;
  128. lft x2=hround u-eps; bot y2=-d-eps;
  129. draw z1--z2;  % diagonal
  130. draw (quartercircle rotated -90 & halfcircle) scaled .1875h shifted 
  131. (.25w,.8562h); % number 3
  132. draw (halfcircle rotated -180 & quartercircle) scaled .1875h shifted 
  133. (.25w,.6687h);
  134. x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
  135. draw z5--z6--z7--z8;
  136. endchar;
  137.  
  138. % From the font cmsy10, file sym.mf
  139. iff known vertical: cmchar "Vertical line";
  140. beginchar(vertical,5u#,body_height#,paren_depth#);
  141. italcorr body_height#*slant+.5rule_thickness#-2u#;
  142. adjust_fit(0,0); pickup rule.nib;
  143. x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
  144. draw z1--z2;  % stem
  145. labels(1,2); endchar;
  146.  
  147. % My own creation
  148. cmchar "Rule";
  149. beginchar(oct"005",12u#,x_height#,.7u#);
  150. italcorr .5x_height#*slant-.5u#;
  151. adjust_fit(0,0);
  152. numeric below_baseline; below_baseline#:=.2u#;
  153. define_pixels(below_baseline);
  154. define_blacker_pixels(thickness);
  155. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  156. top y1r=top y2r=vround(-below_baseline); rt x2=hround(w+6u#);
  157. lft x1=hround(0);
  158. filldraw stroke z1e--z2e;  % bar
  159. penlabels(1,2); endchar;
  160.  
  161. % My own creation
  162. cmchar "Underscore";
  163. beginchar("_",12u#,x_height#,.7u#);
  164. italcorr .5x_height#*slant-.5u#;
  165. adjust_fit(0,0);
  166. numeric below_baseline; below_baseline#:=.2u#;
  167. define_pixels(below_baseline);
  168. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  169. top y1r=top y2r=vround(-below_baseline); x2=hround(w);
  170. x1=hround 0;
  171. filldraw stroke z1e--z2e;  % bar
  172. penlabels(1,2); endchar;
  173.  
  174. % Hyphen from cmr10, file comlig.mf
  175. cmchar "Hyphen";
  176. beginchar("-",6u#,x_height#,0);
  177. italcorr .5x_height#*slant-.5u#;
  178. adjust_fit(0,0);
  179. numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
  180. pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
  181. top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
  182. if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
  183. filldraw stroke z1e--z2e;  % bar
  184. penlabels(1,2); endchar;
  185.  
  186. % My own creation
  187. cmchar "Cent sign";
  188. beginchar(oct"020",18u#,asc_height#,desc_depth#); autorounded;
  189. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  190. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  191. circle_points; 
  192. x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2]; 
  193. y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
  194. x13=x14=.5[x6,x2]-.3u; y13=y4+2u; y14=y8-2u;
  195. draw z10..z9..z11..z12; draw z13--z14;
  196. labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  197.  
  198. % My own creation
  199. cmchar "Copyright";
  200. beginchar(oct"016",18u#,asc_height#,desc_depth#); autorounded;
  201. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  202. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  203. circle_points; draw_circle;  % circle
  204. x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2]; 
  205. y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
  206. draw z10..z9..z11..z12;
  207. labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  208.  
  209. % My own creation
  210. cmchar "Registered";
  211. beginchar(oct"017",18u#,asc_height#,desc_depth#); autorounded;
  212. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  213. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  214. circle_points; draw_circle;  % circle
  215. x9=x11=x12=.7[x6,x8]; x10=x13=.3[x4,x2]; 
  216. y12=y13=.5[y4,y6]; y9=.5[y6,y8]; y11=.5[y12,y9]; y10=.5[y11,y9];
  217. x14=.08[x4,x2]; y14=y9; 
  218. path p;
  219. p=z9--z14{dir 0}..z10..{dir 180}z11;
  220. z15=point 2.6 of p;
  221. draw z12--z9; draw z13--z15; draw p;
  222. labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
  223.  
  224. % Stolen from the font cmr10, file accent.mf (actually the acute accent)
  225. cmchar "Footmark";
  226. beginchar(oct"015",9u#,min(asc_height#,2x_height#),0);
  227. italcorr h#*slant-if serifs: 1.5 fi u#;
  228. adjust_fit(0,0);
  229. if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
  230.  y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
  231.  numeric theta; theta=angle(z2-z1)+90;
  232.  pos1(stem,theta); pos2(hair,theta);
  233.  filldraw circ_stroke z1e--z2e;  % diagonal
  234. else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
  235.  rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
  236.  top y1=h; bot y2=vround 2/3[h,x_height];
  237.  filldraw stroke z1e--z2e; fi  % diagonal
  238. penlabels(1,2); endchar;
  239.  
  240. % Stolen from the font cmsy10, file symbol.mf
  241. cmchar "Dagger mark";
  242. beginchar(oct"014",8u#,asc_height#,desc_depth#);
  243. adjust_fit(0,0); pickup fine.nib;
  244. pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
  245. pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
  246. x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  247. x5-.5stem=hround u; x6=w-x5;
  248. y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
  249. y5+.5stem=floor(x_height+.5stem);
  250. filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e;  % stem
  251. filldraw circ_stroke z5e{right}..{right}z2'e;  % left bulb
  252. filldraw circ_stroke z6e{left}..{left}z2'e;  % right bulb
  253. penlabels(1,2,3,4,5,6); endchar;
  254.  
  255. % Stolen from the font cmr10, file accent.mf (the Scandinavian circle accent)
  256. cmchar "Degree";
  257. beginchar(oct"013",13u#+4/3(asc_height#-x_height#)*slant,asc_height#,0);
  258. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  259. numeric circ_hair,circ_vair;
  260. circ_hair=hround min(hair,u+.5); circ_vair=vround min(vair,(h-x_height)/6+.5);
  261. penpos1(circ_vair,90); penpos3(circ_vair,-90);
  262. penpos2(circ_hair,180); penpos4(circ_hair,0);
  263. x2r=hround(.5w-1.5u-.5circ_hair);
  264. x4r=w-x2r; x1=x3=.5w; y1r=h+apex_o; y2=y4=.5[y1,y3];
  265. y3r=vround(1/3[x_height,h]+apex_o);
  266. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  267.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  268. penlabels(1,2,3,4); endchar;
  269.  
  270. % My own creation
  271. cmchar "Square";
  272. beginchar(oct"010",9u#,v_center(7u#));
  273. italcorr math_axis#*slant;
  274. adjust_fit(0,0); pickup rule.nib;
  275. draw unitsquare scaled 7u shifted (.5w-7u/2,math_axis-7u/2);
  276. endchar;
  277.  
  278. % Stolen from the font cmsy10, file symbol.mf
  279. cmchar "Bullet";
  280. beginchar(oct"007",9u#,v_center(7u#));
  281. adjust_fit(0,0); pickup rule.nib; autorounded;
  282. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
  283. filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
  284.   ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;  % circle and interior
  285. labels(1,2,3,4,5,6,7,8); endchar;
  286.  
  287. % Stolen from the font cmsy10, file sym.mf
  288. iff known minus: cmchar "Minus sign";
  289. beginarithchar(minus); pickup rule.nib;
  290. lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
  291. draw z1--z2;  % bar
  292. labels(1,2); endchar;
  293.  
  294. input romanu;  % upper case (majuscules)
  295. input romanl;  % lower case (minuscules)
  296. input romand;  % numerals
  297. input romanp;  % ampersand, question marks, currency sign
  298. input tpunct;  % punctuation symbols common to roman and italic text
  299. if ligs>1: input tromlig; fi  % letter ligatures
  300. if ligs>0: input tcomlig; fi  % ligatures common with italic text
  301. if ligs<=1: input romsub; fi  % substitutes for ligatures
  302.  
  303. font_slant slant; font_x_height x_height#;
  304. if monospace: font_normal_space 9u#; % no stretching or shrinking
  305.  font_quad 18u#;
  306.  font_extra_space 9u#;
  307. else: font_normal_space 6u#+2letter_fit#;
  308.  font_normal_stretch 3u#; font_normal_shrink 2u#;
  309.  font_quad 18u#+4letter_fit#;
  310.  font_extra_space 2u#;
  311.  k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
  312.  ligtable "k": if serifs: "v": "a" kern -u#, fi\\"w": "e" kern k#,
  313.   "a" kern k#, "o" kern k#, "c" kern k#;
  314.  ligtable "P": "A" kern kk#,
  315.   "y": "o" kern k#, "e" kern k#, "a" kern k#, "." kern kk#, "," kern kk#;
  316.  ligtable "F": "V": "W": if serifs: "o" kern kk#, "e" kern kk#, "u" kern kk#,
  317.     "r" kern kk#, "a" kern kk#, "A" kern kkk#,
  318.    else: "o" kern k#, "e" kern k#, "u" kern k#,
  319.     "r" kern k#, "a" kern k#, "A" kern kk#, fi
  320.   "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
  321.  ligtable "T": "y" kern if serifs: k# else: kk# fi,
  322.   "Y": "e" kern kk#, "o" kern kk#,
  323.    "r" kern kk#, "a" kern kk#, "A" kern kk#, "u" kern kk#;
  324.  ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
  325.    "V" kern k#, "Y" kern k#;
  326.  if serifs: ligtable "h": "m": "n":
  327.    "t" kern k#, "u" kern k#, "b" kern k#, "y" kern k#, "v" kern k#, "w" kern k#;
  328.   ligtable "c": "h" kern k#, "k" kern k#; fi
  329.  ligtable "o": "b": "p": "e" kern -k#, "o" kern -k#, "x" kern k#,
  330.    "d" kern -k#, "c" kern -k#, "q" kern -k#,
  331.   "a": if serifs: "v" kern k#, "j" kern u#, else: "r" kern k#, fi
  332.   "t": "y" kern k#,
  333.   "u": "w" kern k#;
  334.  ligtable "A": if serifs: "R": fi\\ "t" kern k#,
  335.   "C" kern k#, "O" kern k#, "G" kern k#, "U" kern k#, "Q" kern k#,
  336.   "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#;
  337.  ligtable "g": "j" kern -k#; % logjam
  338.  ligtable "I": "I" kern -k#; fi % Richard III
  339.  % there are ligature/kern programs for |"f"| in the {\tt romlig} file
  340.  % and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
  341. bye.
  342.